home *** CD-ROM | disk | FTP | other *** search
/ SGI Developer Toolbox 6.1 / SGI Developer Toolbox 6.1 - Disc 4.iso / lib / mathlib / libblas / src_original / stpmv.f < prev    next >
Encoding:
Text File  |  1994-08-02  |  9.3 KB  |  303 lines
  1. *
  2. ************************************************************************
  3. *
  4.       SUBROUTINE STPMV ( UPLO, TRANS, DIAG, N, AP, X, INCX )
  5. *     .. Scalar Arguments ..
  6.       INTEGER            INCX, N
  7.       CHARACTER*1        DIAG, TRANS, UPLO
  8. *     .. Array Arguments ..
  9.       REAL               AP( * ), X( * )
  10. *     ..
  11. *
  12. *  Purpose
  13. *  =======
  14. *
  15. *  STPMV  performs one of the matrix-vector operations
  16. *
  17. *     x := A*x,   or   x := A'*x,
  18. *
  19. *  where x is an n element vector and  A is an n by n unit, or non-unit,
  20. *  upper or lower triangular matrix, supplied in packed form.
  21. *
  22. *  Parameters
  23. *  ==========
  24. *
  25. *  UPLO   - CHARACTER*1.
  26. *           On entry, UPLO specifies whether the matrix is an upper or
  27. *           lower triangular matrix as follows:
  28. *
  29. *              UPLO = 'U' or 'u'   A is an upper triangular matrix.
  30. *
  31. *              UPLO = 'L' or 'l'   A is a lower triangular matrix.
  32. *
  33. *           Unchanged on exit.
  34. *
  35. *  TRANS  - CHARACTER*1.
  36. *           On entry, TRANS specifies the operation to be performed as
  37. *           follows:
  38. *
  39. *              TRANS = 'N' or 'n'   x := A*x.
  40. *
  41. *              TRANS = 'T' or 't'   x := A'*x.
  42. *
  43. *              TRANS = 'C' or 'c'   x := A'*x.
  44. *
  45. *           Unchanged on exit.
  46. *
  47. *  DIAG   - CHARACTER*1.
  48. *           On entry, DIAG specifies whether or not A is unit
  49. *           triangular as follows:
  50. *
  51. *              DIAG = 'U' or 'u'   A is assumed to be unit triangular.
  52. *
  53. *              DIAG = 'N' or 'n'   A is not assumed to be unit
  54. *                                  triangular.
  55. *
  56. *           Unchanged on exit.
  57. *
  58. *  N      - INTEGER.
  59. *           On entry, N specifies the order of the matrix A.
  60. *           N must be at least zero.
  61. *           Unchanged on exit.
  62. *
  63. *  AP     - REAL             array of DIMENSION at least
  64. *           ( ( n*( n + 1 ) )/2 ).
  65. *           Before entry with  UPLO = 'U' or 'u', the array AP must
  66. *           contain the upper triangular matrix packed sequentially,
  67. *           column by column, so that AP( 1 ) contains a( 1, 1 ),
  68. *           AP( 2 ) and AP( 3 ) contain a( 1, 2 ) and a( 2, 2 )
  69. *           respectively, and so on.
  70. *           Before entry with UPLO = 'L' or 'l', the array AP must
  71. *           contain the lower triangular matrix packed sequentially,
  72. *           column by column, so that AP( 1 ) contains a( 1, 1 ),
  73. *           AP( 2 ) and AP( 3 ) contain a( 2, 1 ) and a( 3, 1 )
  74. *           respectively, and so on.
  75. *           Note that when  DIAG = 'U' or 'u', the diagonal elements of
  76. *           A are not referenced, but are assumed to be unity.
  77. *           Unchanged on exit.
  78. *
  79. *  X      - REAL             array of dimension at least
  80. *           ( 1 + ( n - 1 )*abs( INCX ) ).
  81. *           Before entry, the incremented array X must contain the n
  82. *           element vector x. On exit, X is overwritten with the
  83. *           tranformed vector x.
  84. *
  85. *  INCX   - INTEGER.
  86. *           On entry, INCX specifies the increment for the elements of
  87. *           X. INCX must not be zero.
  88. *           Unchanged on exit.
  89. *
  90. *
  91. *  Level 2 Blas routine.
  92. *
  93. *  -- Written on 22-October-1986.
  94. *     Jack Dongarra, Argonne National Lab.
  95. *     Jeremy Du Croz, Nag Central Office.
  96. *     Sven Hammarling, Nag Central Office.
  97. *     Richard Hanson, Sandia National Labs.
  98. *
  99. *
  100. *     .. Parameters ..
  101.       REAL               ZERO
  102.       PARAMETER        ( ZERO = 0.0E+0 )
  103. *     .. Local Scalars ..
  104.       REAL               TEMP
  105.       INTEGER            I, INFO, IX, J, JX, K, KK, KX
  106.       LOGICAL            NOUNIT
  107. *     .. External Functions ..
  108.       LOGICAL            LSAME
  109.       EXTERNAL           LSAME
  110. *     .. External Subroutines ..
  111.       EXTERNAL           XERBLA
  112. *     ..
  113. *     .. Executable Statements ..
  114. *
  115. *     Test the input parameters.
  116. *
  117.       INFO = 0
  118.       IF     ( .NOT.LSAME( UPLO , 'U' ).AND.
  119.      $         .NOT.LSAME( UPLO , 'L' )      )THEN
  120.          INFO = 1
  121.       ELSE IF( .NOT.LSAME( TRANS, 'N' ).AND.
  122.      $         .NOT.LSAME( TRANS, 'T' ).AND.
  123.      $         .NOT.LSAME( TRANS, 'C' )      )THEN
  124.          INFO = 2
  125.       ELSE IF( .NOT.LSAME( DIAG , 'U' ).AND.
  126.      $         .NOT.LSAME( DIAG , 'N' )      )THEN
  127.          INFO = 3
  128.       ELSE IF( N.LT.0 )THEN
  129.          INFO = 4
  130.       ELSE IF( INCX.EQ.0 )THEN
  131.          INFO = 7
  132.       END IF
  133.       IF( INFO.NE.0 )THEN
  134.          CALL XERBLA( 'STPMV ', INFO )
  135.          RETURN
  136.       END IF
  137. *
  138. *     Quick return if possible.
  139. *
  140.       IF( N.EQ.0 )
  141.      $   RETURN
  142. *
  143.       NOUNIT = LSAME( DIAG, 'N' )
  144. *
  145. *     Set up the start point in X if the increment is not unity. This
  146. *     will be  ( N - 1 )*INCX  too small for descending loops.
  147. *
  148.       IF( INCX.LE.0 )THEN
  149.          KX = 1 - ( N - 1 )*INCX
  150.       ELSE IF( INCX.NE.1 )THEN
  151.          KX = 1
  152.       END IF
  153. *
  154. *     Start the operations. In this version the elements of AP are
  155. *     accessed sequentially with one pass through AP.
  156. *
  157.       IF( LSAME( TRANS, 'N' ) )THEN
  158. *
  159. *        Form  x:= A*x.
  160. *
  161.          IF( LSAME( UPLO, 'U' ) )THEN
  162.             KK =1
  163.             IF( INCX.EQ.1 )THEN
  164.                DO 20, J = 1, N
  165.                   IF( X( J ).NE.ZERO )THEN
  166.                      TEMP = X( J )
  167.                      K    = KK
  168.                      DO 10, I = 1, J - 1
  169.                         X( I ) = X( I ) + TEMP*AP( K )
  170.                         K      = K      + 1
  171.    10                CONTINUE
  172.                      IF( NOUNIT )
  173.      $                  X( J ) = X( J )*AP( KK + J - 1 )
  174.                   END IF
  175.                   KK = KK + J
  176.    20          CONTINUE
  177.             ELSE
  178.                JX = KX
  179.                DO 40, J = 1, N
  180.                   IF( X( JX ).NE.ZERO )THEN
  181.                      TEMP = X( JX )
  182.                      IX   = KX
  183.                      DO 30, K = KK, KK + J - 2
  184.                         X( IX ) = X( IX ) + TEMP*AP( K )
  185.                         IX      = IX      + INCX
  186.    30                CONTINUE
  187.                      IF( NOUNIT )
  188.      $                  X( JX ) = X( JX )*AP( KK + J - 1 )
  189.                   END IF
  190.                   JX = JX + INCX
  191.                   KK = KK + J
  192.    40          CONTINUE
  193.             END IF
  194.          ELSE
  195.             KK = ( N*( N + 1 ) )/2
  196.             IF( INCX.EQ.1 )THEN
  197.                DO 60, J = N, 1, -1
  198.                   IF( X( J ).NE.ZERO )THEN
  199.                      TEMP = X( J )
  200.                      K    = KK
  201.                      DO 50, I = N, J + 1, -1
  202.                         X( I ) = X( I ) + TEMP*AP( K )
  203.                         K      = K      - 1
  204.    50                CONTINUE
  205.                      IF( NOUNIT )
  206.      $                  X( J ) = X( J )*AP( KK - N + J )
  207.                   END IF
  208.                   KK = KK - ( N - J + 1 )
  209.    60          CONTINUE
  210.             ELSE
  211.                KX = KX + ( N - 1 )*INCX
  212.                JX = KX
  213.                DO 80, J = N, 1, -1
  214.                   IF( X( JX ).NE.ZERO )THEN
  215.                      TEMP = X( JX )
  216.                      IX   = KX
  217.                      DO 70, K = KK, KK - ( N - ( J + 1 ) ), -1
  218.                         X( IX ) = X( IX ) + TEMP*AP( K )
  219.                         IX      = IX      - INCX
  220.    70                CONTINUE
  221.                      IF( NOUNIT )
  222.      $                  X( JX ) = X( JX )*AP( KK - N + J )
  223.                   END IF
  224.                   JX = JX - INCX
  225.                   KK = KK - ( N - J + 1 )
  226.    80          CONTINUE
  227.             END IF
  228.          END IF
  229.       ELSE
  230. *
  231. *        Form  x := A'*x.
  232. *
  233.          IF( LSAME( UPLO, 'U' ) )THEN
  234.             KK = ( N*( N + 1 ) )/2
  235.             IF( INCX.EQ.1 )THEN
  236.                DO 100, J = N, 1, -1
  237.                   TEMP = X( J )
  238.                   IF( NOUNIT )
  239.      $               TEMP = TEMP*AP( KK )
  240.                   K = KK - 1
  241.                   DO 90, I = J - 1, 1, -1
  242.                      TEMP = TEMP + AP( K )*X( I )
  243.                      K    = K    - 1
  244.    90             CONTINUE
  245.                   X( J ) = TEMP
  246.                   KK     = KK   - J
  247.   100          CONTINUE
  248.             ELSE
  249.                JX = KX + ( N - 1 )*INCX
  250.                DO 120, J = N, 1, -1
  251.                   TEMP = X( JX )
  252.                   IX   = JX
  253.                   IF( NOUNIT )
  254.      $               TEMP = TEMP*AP( KK )
  255.                   DO 110, K = KK - 1, KK - J + 1, -1
  256.                      IX   = IX   - INCX
  257.                      TEMP = TEMP + AP( K )*X( IX )
  258.   110             CONTINUE
  259.                   X( JX ) = TEMP
  260.                   JX      = JX   - INCX
  261.                   KK      = KK   - J
  262.   120          CONTINUE
  263.             END IF
  264.          ELSE
  265.             KK = 1
  266.             IF( INCX.EQ.1 )THEN
  267.                DO 140, J = 1, N
  268.                   TEMP = X( J )
  269.                   IF( NOUNIT )
  270.      $               TEMP = TEMP*AP( KK )
  271.                   K = KK + 1
  272.                   DO 130, I = J + 1, N
  273.                      TEMP = TEMP + AP( K )*X( I )
  274.                      K    = K    + 1
  275.   130             CONTINUE
  276.                   X( J ) = TEMP
  277.                   KK     = KK   + ( N - J + 1 )
  278.   140          CONTINUE
  279.             ELSE
  280.                JX = KX
  281.                DO 160, J = 1, N
  282.                   TEMP = X( JX )
  283.                   IX   = JX
  284.                   IF( NOUNIT )
  285.      $               TEMP = TEMP*AP( KK )
  286.                   DO 150, K = KK + 1, KK + N - J
  287.                      IX   = IX   + INCX
  288.                      TEMP = TEMP + AP( K )*X( IX )
  289.   150             CONTINUE
  290.                   X( JX ) = TEMP
  291.                   JX      = JX   + INCX
  292.                   KK      = KK   + ( N - J + 1 )
  293.   160          CONTINUE
  294.             END IF
  295.          END IF
  296.       END IF
  297. *
  298.       RETURN
  299. *
  300. *     End of STPMV .
  301. *
  302.       END
  303.